/*************************************************************/
/*                                                           */
/* Copyright (C) Microsoft Corporation. All rights reserved. */
/*                                                           */
/*************************************************************/

import Colors 1.0
import Fonts 1.0
import QtQuick 2.7
import QtQuick.Controls 2.2
import QtQuick.Controls.Styles 1.4

Rectangle {
    id: root
    anchors.fill: parent
    color: "transparent"

    onVisibleChanged: { if (visible) openFolderButton.forceActiveFocus(); }

    WizardPageHeader {
        id: header
        anchors {
            top: parent.top
            left: parent.left
            right: parent.right
        }

        title.text: _("KfmMigrationErrorsPageTitle")
        subtitle.visible: false
        subtitle.anchors.topMargin: 35

        image.source: "file:///" + imageLocation + "exclamation.svg"
        image.sourceSize.width: 235
        image.sourceSize.height: 216

        image.anchors.top: header.top
        image.anchors.topMargin: 173

        property bool wasAnnounced : false
        function announceOnce() {
            if (!header.wasAnnounced) {
                header.wasAnnounced = true;
                wizardWindow.announceTextChange(header.title, _("MoveWindowTitleDone"), Accessible.AnnouncementProcessing_ImportantAll);
            }
        }

        onVisibleChanged: {
            if (visible) {
                header.announceOnce();
            }
        }

        TextWithLink {
            id: infoAreaText
            objectName: "infoAreaText"
            embeddedLinkModel: pageModel.infoAreaText

            font.family: Fonts.standard
            font.pixelSize: 14
            color: Colors.common.text_secondary

            horizontalAlignment: Text.Center
            wrapMode: Text.WordWrap
            anchors {
                top: header.title.bottom
                topMargin: 35

                left: parent.left
                leftMargin: 35

                right: parent.right
                rightMargin: 35
            }

            property string accessibleText : infoAreaText.embeddedLinkModel.accessibleText

            Accessible.role: Accessible.StaticText
            Accessible.name: accessibleText
            Accessible.readOnly: true

            onLinkActivated: {
                pageModel.onEmbeddedLinkActivated(text, 0);
            }

            callback: function(text, index) {
                pageModel.onEmbeddedLinkActivated(text, index);
            }
        }
    }

    FabricButton {
        id: openFolderButton
        visible: true
        focus: true
        onClicked: pageModel.onOpenFolderClicked();
        buttonText: pageModel.hasMultipleFolders ? _("GenericOpenFolderPlural") : _("GenericOpenFolder")
        buttonStyle: "primary"

        anchors {
            bottom: parent.bottom
            bottomMargin: 30

            right: skipButton.left
            rightMargin: 12
        }

        Accessible.onPressAction: onClicked()
        Keys.onEnterPressed: onClicked()
        Keys.onReturnPressed: onClicked()
        Keys.onSpacePressed: onClicked()
    }

    FabricButton {
        id: skipButton
        visible: true
        focus: true
        onClicked: pageModel.onNextButtonClicked();
        buttonText: pageModel.nextButtonText
        buttonStyle: "standard"

        anchors {
            bottom: parent.bottom
            bottomMargin: 30

            right: parent.right
            rightMargin: 35
        }

        Accessible.onPressAction: onClicked()
        Keys.onEnterPressed: onClicked()
        Keys.onReturnPressed: onClicked()
        Keys.onSpacePressed: onClicked()
    }
}